翻訳 link

主言語と副言語 link

Ren'Py は、それぞれのゲームが1つの主言語によって書かれていると想定します。このときの言語は None 言語と呼ばれますが、その言語が実際に何であっても構いません(例えば、ゲームが英語で書かれている場合は、英語が None 言語となります)。

None 言語が選択されたときは、Ren'Py のほとんどの翻訳機能が無効化されます。

副言語は、Python の識別子としても振る舞える名前によって関連付けられます(英字またはアンダースコアで始まり、英数字とアンダースコアが続きます)。

翻訳ファイルの生成 link

プロジェクトのスクリプトが利用できる場合、Ren'Py ランチャーでプロジェクトを開き「Generate Translations」を選んで翻訳ファイルを生成できます。ランチャーは生成する言語の名前の入力を求めた後、翻訳ファイルの作成または更新を行います。

翻訳ファイルはゲームディレクトリーの中の「tl」サブディレクトリーの下に設置されます。例えばチュートリアルプロジェクトの piglatin の翻訳を作成した場合、翻訳ファイルは tutorial/game/tl/piglatin の下に設置されます。

ゲームのスクリプトファイル1つに対して翻訳ファイルが1つ作成されます。共通のコードで見つかった文字列の翻訳を含めるために、common.rpy ファイルも作成されます。

台詞の翻訳 link

Ren'Py ビジュアルノベルエンジンの開発者としては、ほとんどの翻訳が台詞と対応することを期待しています。Ren'Py には柔軟なフレームワークがあり、台詞の分割、結合、並べ替え、完全な省略を行えます。

label start:
    e "Thank you for taking a look at the Ren'Py translation framework."

    show eileen happy

    e "We aim to provide a comprehensive framework for translating dialogue, strings, images, and styles."

    e "Pretty much everything your game needs!"

e "Thank you for taking a look at the Ren'Py translation framework."

e "We aim to provide a comprehensive framework for translating dialogue, strings, images, and styles."

e "Pretty much everything your game needs!"

# game/script.rpy:95
translate piglatin start_636ae3f5:

    # e "Thank you for taking a look at the Ren'Py translation framework."
    e ""

# game/script.rpy:99
translate piglatin start_bd1ad9e1:

    # e "We aim to provide a comprehensive framework for translating dialogue, strings, images, and styles."
    e ""

# game/script.rpy:101
translate piglatin start_9e949aac:

    # e "Pretty much everything your game needs!"
    e ""

# game/script.rpy:95
translate piglatin start_636ae3f5:
    # e "Thank you for taking a look at the Ren'Py translation framework."
    e "Ankthay ouyay orfay akingtay away ooklay atway ethay En'Pyray anslationtray ameworkfray."

# game/script.rpy:99
translate piglatin start_bd1ad9e1:

    # e "We aim to provide a comprehensive framework for translating dialogue, strings, images, and styles."
    e "Eway aimway otay ovidepray away omprehensivecay ameworkfray orfay anslatingtray ialogueday, ingsstray, imagesway, andway ylesstay."

# game/script.rpy:101
translate piglatin start_9e949aac:

    # e "Pretty much everything your game needs!"
    e "Ettypray uchmay everythingway ouryay amegay eedsnay!"

# game/script.rpy:99
translate piglatin start_bd1ad9e1:
    # e "We aim to provide a comprehensive framework for translating dialogue, strings, images, and styles."
    e "Eway aimway otay ovidepray away omprehensivecay ameworkfray..."
    e "...orfay anslatingtray ialogueday, ingsstray, imagesway, andway ylesstay."

# game/script.rpy:101
translate piglatin start_9e949aac:

     # e "Pretty much everything your game needs!"
     pass

e "You scored [points] points!"

# game/script.rpy:103
translate piglatin start_36562aba:

    # e "You scored [points] points!"
    $ latin_points = to_roman_numerals(points)
    e "Ouyay oredscay [latin_points] ointspay!"

translate None mylabel_03ac197e_1:
    "..."

label ignored_by_translation hide:
    "..."

メニューと文字列の翻訳 link

台詞に加えて Ren'Py ではメニューのテキストやその他の文字列を翻訳できます。インターフェイスの翻訳は1対1で対応しています。文字列が見つかると、それは単一の文字列で置換されます。

翻訳の生成時に、Ren'Py はスクリプトファイルのメニュー、及び _() 関数で囲まれた文字列をスキャンします。すると、translate strings ブロック内にスキャンされた文字列が設置されます。例えば、次のコードがあったとします:

define e = Character(_("Eileen"))

# ...

menu:

     "Go West":
        # ...

     "Head East":
        # ...

Ren'Py は次のコードを生成します

translate piglatin strings:

    old "Eileen"
    new ""

    old "Go West"
    new ""

    old "Head East"
    new ""

これは次のように翻訳できます:

translate piglatin strings:

    old "Eileen"
    new "Eileenway"

    old "Go West"
    new "Ogay Estway"

    old "Head East"
    new "Eadhay Eastway"

String translation は台詞としては翻訳されない台詞の文字列にも適用されます。

コード中で同一の文字列が複数の場所に存在する場合、文字列は {#...} テキストタグを使って見分けられます。次のようにした場合、それぞれの文字列は同じように表示されますが、Ren'Py は翻訳のための異なる文字列として認識します

"New"
"New{#project}"
"New{#game}"
"New{#playlist}"

translate strings ステートメントは、None 言語の翻訳にも使用できます。これは、英語以外の言語で制作されたゲームに対し、Ren'Py ユーザーインターフェイスを翻訳する場合に利用できます。:

translate None strings:
     old "Start Game"
     new "Artstay Amegay"

if mood_points > 5:
    $ mood = _("great")
else:
    $ mood = _("awful")

"I'm feeling [mood!t]."

画像とファイルの翻訳 link

ゲームを翻訳するとき、ファイルを翻訳版に置き換える必要があるかもしれません。例えば画像にテキストが含まれている場合、意味が分かるようにテキスト部分が別の言語で書かれた画像に置き換えるでしょう。

このような場合に Ren'Py は画像を翻訳ディレクトリーの中から探します。例えば「piglatin」言語において「library.png」を読み込むとき、Ren'Py は「game/tl/piglatin/library.png」を「game/library.png」よりも優先して使います。

スタイルの翻訳 link

ゲームの翻訳時に、スタイルの変更 (特にフォント関係のスタイル) が必要になるでしょう。Ren'Py ではこれに対し translate style ブロックと translate python ブロックで対応しています。これらのブロックには、言語関係の変数やスタイルを変更するためのコードを含められます。例えば

translate piglatin style default:
    font "stonecutter.ttf"

または等価なもので:

translate piglatin python:
    style.default.font = "stonecutter.ttf"

言語が利用可能になった時 (ゲームの開始時、もしくは言語が変更された後)、Ren'Py は init フェーズの後でスタイルをこの内容にリセットし、すべての translate python ブロックを実行します。そして現在の言語に関係するすべての translate style ブロックを実行してファイルの最初にあるブロックが実行されることを保証し、最後にスタイルを再構築して変更を有効にします。

スタイルの翻訳はどのような .rpy ファイルにも追加できます。

既定の言語 link

既定の言語は次の方法によって選択します:

• RENPY_LANGUAGE 環境変数が設定されていれば、その言語が使用されます。

• config.language が設定されていれば、その言語が使用されます。

• 過去にゲームで言語を選択したことがあれば、その言語が使用されます。

• ゲームが最初に開始された時は config.enable_language_autodetect が True になり、 Ren'Py は config.locale_to_language_function を使用して言語の自動検出を試みます。

• ゲームが最初に開始された時は、 config.default_language が使用されます ( このデフォルト値は None 言語です )。

• これら以外の場合は、None 言語が使用されます。

翻訳に関連したアクション、関数、変数 link

言語を切り替える主な方法は、Language アクションを使うことです。

Language(language) link

ゲームの言語を language に変更します。

language

翻訳先の言語の文字列、または None のときはゲームスクリプトの既定の言語を使います。

Language アクションを使うと、次のようなコードを使って設定画面に言語設定を追加できます

frame:
    style_prefix "pref"
    has vbox

    label _("Language")
    textbutton "English" action Language(None)
    textbutton "Igpay Atinlay" action Language("piglatin")

翻訳関連の関数は2つあります:

renpy.change_language(language, force=False) link

現在の言語を language に変更します。この値は文字列、または既定の言語の場合は None にできます。

renpy.known_languages() link

既知の言語のセットを返します。これには既定の言語 None は含まれません。

さらに、文字列の翻訳に関連した 4 つの関数があります:

_(s) link

(単一のアンダースコア) s を変更せずに返します。Ren'Py はこの関数で囲まれた文字列をスキャンし、翻訳可能な文字列のリストにそれを追加します。文字列は表示されるまで翻訳されません。

__(s) link

(2重アンダースコア) s を現在の言語に直ちに翻訳して返します。この関数で囲まれた文字列は、翻訳可能な文字列のリストに追加されます。翻訳後の文字列が表示される時に、文字列翻訳にマッチすると文字列が2重に翻訳されてしまうことに注意してください。

_p(s) link

文字列再フォーマットし、翻訳可能としてフラグをつけます。文字列はテキスト displayable で表示されるときに翻訳されます。これは次の形式で、文字列で使用する複数行を定義することを意図しています。

define config.about = _p("""
    These two lines will be combined together
    to form a long line.

    This line will be separate.
    """)

再フォーマットは、各行の最初と最後のホワイトスペースを除去してテキストを1つの行にします。このとき空白行は最後に除去され、空白行があるときは、空白行に分離パラグラフが挿入されます。 {p} タグは行を改行し、空白行は追加しません。

これは文字列の翻訳において、次のように使用できます。

old "These two lines will be combined together to form a long line.\n\nThis line will be separate."
new _p("""
    These two lines will be combined together
    to form a long line. Bork bork bork.

    This line will be separate. Bork bork bork.
    """)

renpy.translate_string(s, language=<renpy.object.Sentinel object at 0x7fe3ea7e0650>) link

s を language に直ちに翻訳して返します。 language が未指定なら、 preferences で設定された言語を使用します。この関数で囲まれた文字列は、 not 翻訳可能文字列のリストに追加されません。翻訳後の文字列が表示される時に文字列翻訳にマッチすると二重翻訳されるので注意してください。

言語関連の変数は2つあります。1つは config.language で、これはゲームの既定の言語を変更するために使用されます。

_preferences.language link

現在の言語の名前、または既定の言語が使われている場合は None。これは読み込み専用の変数として扱わなければなりません。言語を変更するには renpy.change_language() を使用して下さい。

正式な認可を受けていない場合の翻訳 link

Ren'Py はゲーム制作者からの十分な支援が無い場合の翻訳の作成に、少しだけ対応しています。これはゲームのすべての文字列から自動的に文字列翻訳ファイルを作成する機能です。未翻訳の台詞に対して文字列翻訳を行う方法によりゲームの翻訳が可能となります。

文字列翻訳ファイルの作成は、次の手順で行います:

• RENPY_LANGUAGE 環境変数を翻訳先にしたい言語に設定します。

• RENPY_UPDATE_STRINGS 環境変数を空でない値に設定します。

• すべてのテキストが表示されるまでゲームを動かします。

これにより "game/tl/language/strings.rpy" ファイルが更新され、すべてのテキストが含まれた翻訳の雛形となります。

ゲームに言語切り替え機能が含まれていない場合は、 init python ブロックで config.language にその言語を設定するのが適切でしょう。

台詞の文字列翻訳を使った場合、認可を受けていない翻訳者は画像やスタイルの翻訳に対して上記で説明した方法は使えません。