オーディオ link

Ren'Py は以下のフォーマットのファイルを使用したバックグラウンドでの音楽、効果音再生をサポートしています。

  • OPUS
  • OGG Vorbis
  • MP3
  • WAV (非圧縮 PCM のみ)

Ren'Py は任意の数のオーディオチャンネルをサポートしています。デフォルトでは 3 つのノーマルチャンネルが定義されています。 :

  • music - 音楽再生用チャンネル。

  • sound - サウンドエフェクト用チャンネル。

  • voice - ボイス再生用チャンネル。

ノーマルチャンネルはオーディオの再生、キューに対応しますが、同時にひとつのオーディオファイルのみ再生します。新しいノーマルチャンネルは renpy.music.register_channel() で登録されます。

ゲーム内で設定画面の 'Music Volume', 'Sound Volume', 'Voice Volume' を設定してそれぞれのチャンネルの個々のボリュームを設定できます。

ノーマルチャンネルに加えて、特別なチャンネル audio があります。この audio チャンネルは同時に複数のオーディオの再生をサポートしますが、サウンドのキューや再生の停止はサポートしません。

サウンドはボタンや選択肢、イメージマップがフォーカスを持つか押されると再生するようにも設定出来ます。 Button Style Properties を参照してください。 2 つの設定変数 config.main_menu_musicconfig.game_menu_music それぞれ指定されたオーディオファイルをメインメニューとゲームメインメニューで再生するように出来ます。

ゲーム中に、 Ren'Py で曲と効果音を再生する通常の方法は 3 つの music/sound ステートメントを使用することです。

play ステートメント link

play ステートメントは曲や効果音を再生するために使用されます。ファイルが通常のノーマルチャンネルで再生中なら、停止して新しいファイルで置き換えます。

チャンネル名がキーワード play に続くことが期待されます。 ( 通常これは「sound 」、「 music 」「 voice 」のいずれかです。 ) この後にはオーディオファイルかファイルのリストが続きます。リストが指定されるとその要素が順番に再生されます。

fadeinfadeout 節は任意です。 fadeout は現在再生中の曲をフェードアウトする時間を秒数で指定し、 fadein は新しい曲をフェードインするのにかかる時間を指定します。 fadeout が指定されていないと、 config.fade_music が使用されます。

loop, noloop 節も任意です。 loop 節は曲をループし、 noloop 節は一度だけ再生します。両方とも指定されない場合はチャンネルのデフォルトが使用されます。

play music "mozart.ogg"
play sound "woof.mp3"
play myChannel "punch.wav" # 'myChannel' needs to be defined with renpy.music.register_channel().

"We can also play a list of sounds, or music."
play music [ "a.ogg", "b.ogg" ] fadeout 1.0 fadein 1.0

この auido チャンネルでは複数の play ステートメントで同時に複数のサウンドを再生します。

play audio "sfx1.opus"
play audio "sfx2.opus"

stop ステートメント link

stop ステートメントはキーワード stop で始まり、ストップする チャンネルが続きます。任意で fadeout 節も持ちます。

stop sound
stop music fadeout 1.0

queue ステートメント link

queue ステートメントはオーディオファイルをキューするために使用されます。それらはチャンネルが現在再生中のファイルを終了すると再生されます。

queue ステートメントはキーワード queue で始まり、再生するチャンネルの名前が続きます。任意で loopnoloop 節を取ります。

queue sound "woof.ogg"
queue music [ "a.ogg", "b.ogg" ]

これらのステートメントを使用する利点は lint を実行時にオーディオファイルの消失をチェック出来ることです。以下の関数は曲と効果音を python から制御出来るようにし、 ( 滅多に使用されませんが ) 先進的な機能を利用するために存在します。

部分再生 link

Ren'Py はオーディオファイルの部分的な再生をサポートします。このためにはファイルの始めの山括弧のなかで位置を指定します。部分再生指定は適切な名前と値のペアからなり、それぞれスペースで区切られます。

値はファイルの開始からの秒数と解釈されます。3つのプロパティー :

from

最初に再生を開始するときの位置を指定します。 (デフォルトでは 0.0 秒)

to

最初に再生を停止する位置を指定します。 (デフォルトでは 0.0 秒)

loop

二回目からの再生開始位置を指定します。 (デフォルトでは from で指定された開始位置またはそのファイルの開始位置です。 )

play music "<from 5 to 15.5>waves.opus"

5 秒から開始し、 10.5 秒間 waves.opus を再生します。

play music "<loop 6.333>song.opus"

song.opus を一回再生すると、 6.333 秒からループします。

Playing Silence link

3.0 秒の無音が欲しい場合、 "<silence 3.0>" のような名前のファイル名を使用して、指定された時間無音を再生できます。これにより再生位置を遅延できます。 例

play audio [ "<silence .5>", "boom.opus" ]

0.5 秒の無音の後、爆発音を再生します。

Audio ネームスペース link

playqueue ステートメントは audio ネームスペースでその引数を評価します。これにより define ステートメントでオーディオファイルにエイリアスを定義出来ます。

例えばこのように書くと

define audio.sunflower = "music/sun-flower-slow-jam.ogg"

このように使用します。

play music sunflower

関数 link

renpy.play(filename, channel=None, **kwargs) link

効果音を再生します。 channel が None なら、デフォルトで config.play_channel になります。これは hover_soundactivate_sound スタイルで定義されたサウンドを再生します。

renpy.seen_audio(filename) link

指定したファイル名が 1 度でも現在のユーザーに再生されていれば True を返します。

renpy.music.get_duration(channel='music') link

channel のオーディオやビデオの長さを返します。 ファイルが再生されていなければ 0.0 を返します。

renpy.music.get_pause(channel='music') link

channel のポーズフラグを返します。

renpy.music.get_playing(channel='music') link

指定されたチャンネルが再生中の場合、再生中のファイルの名前を返します。それ以外の場合は None を返します。

renpy.music.get_pos(channel='music') link

channel のオーディオやビデオの現在位置を秒数で返します。ファイルが再生されていなければ None を返します。

チャンネルが再生前であったり、ミュートにされると None を返すため、この関数を呼び出すコードは常に None を処理するべきです。

renpy.music.is_playing(channel='music') link

指定されたチャンネルが再生中なら True を返します。再生中でないかサウンドシステムが動作していないなら False を返します。

renpy.music.play(filenames, channel='music', loop=None, fadeout=None, synchro_start=False, fadein=0, tight=None, if_changed=False) link

これは指定されたチャンネルで現在再生中の曲を停止し、キューされた曲をクリアし、指定されたファイルかファイルリストを再生開始します。

filenames

これは再生されるファイルかファイルのリストです。

channel

サウンドを再生するチャンネル

loop

これが True ならトラックはそれがキューの最後にある間ループを続けます。

fadeout

None を指定するか、フェードアウトにかかる秒数を指定します。そうでなければフェードアウトの時間は config.fade_music から取られます。

synchro_start

Ren'Py では、synchro_start が True に設定されたチャンネルの間で、再生の開始を同時に行うことを保証できます。互いに同期させることを意図した2つのオーディオファイルを再生する場合、synchro_start を True に設定すべきです。

fadein

これは曲をフェードインするのにかかる秒数で、最初のループでのみ有効です。

tight

True ならフェードアウトは次にキューされるサウンドにも適用されます。None なら loop が True のとき True になり、そうでなければ false です。

if_changed

これが True でそのオーディオファイルが現在再生中なら、停止やフェードアウトも再び最初から再生もせずに再生を継続します。 ( これは常にそのオーディオファイルをキューに追加します。 )

channel のポーズフラグをクリアします。

renpy.music.queue(filenames, channel='music', loop=None, clear_queue=True, fadein=0, tight=None) link

指定されたファイルを特定のチャンネルにキューします。

filenames

これは再生されるファイルかファイルのリストです。

channel

サウンドを再生するチャンネル

loop

これが True ならトラックはそれがキューの最後にある間ループを続けます。

clear_queue

True なら現在の再生が終了するとキューがクリアされると共にこれらのファイルが再生されます。 False ならこれらのファイルはキューの末尾に配置されます。どちらの場合でも音楽が再生されていなければこれらのファイルは即座に再生開始します。

fadein

これは曲をフェードインするのにかかる秒数で、最初のループでのみ有効です。

tight

True ならフェードアウトは次にキューされるサウンドにも適用されます。None なら loop が True のとき True になり、そうでなければ false です。

channel のポーズフラグをクリアします。

renpy.music.register_channel(name, mixer=None, loop=None, stop_on_mute=True, tight=False, file_prefix='', file_suffix='', buffer_queue=True, movie=False) link

name と名付けられた新しいオーディオチャンネルを登録します。オーディオはチャンネルの名前を play または queue ステートメントに与えると、そのチャンネルで再生されます。

mixer

チャンネルが使用するミキサーの名前。デフォルトで Ren'Py には「 music 」,「 sfx 」,「 voice 」ミキサーが設定されています。他の名前の使用は可能ですが、設定画面の変更も必要かもしれません。

loop

True の場合、このチャンネルのサウンドはデフォルトでループします。

stop_on_mute

True の場合、このチャンネルの曲はチャンネルがミュートになったら停止します。

tight

True の場合、サウンドはフェードアウト中でもループします。これは、サウンドエフェクトやシームレスなミュージックチャンネルに対して True に、曲がそれ自身でフェードアウトする場合は False に設定すべきです。

file_prefix

このチャンネルで再生される曲のファイル名につけられる接頭辞。

file_suffix

このチャンネルで再生される曲のファイル名につけられる接尾辞。

buffer_queue

キューに入れたファイルの最初の数秒をメモリに展開しますか?これはオーディオに対しては True 、ムービーに対しては False にすべきです。

movie

True ならこのチャンネルはビデオ再生用に設定されます。

renpy.music.set_pan(pan, delay, channel='music') link

このチャンネルのパンを設定します。

pan

音源の位置を制御する -1 から 1 までの間の数字です。これが -1 だと全ての音は左側のチャンネルに送られ、 0 だと 2 つのチャンネルは等しくなります。 1 なら全ての音は右側に送られます。

delay

パンの実行に掛ける時間です。

channel

パンを実行するチャンネルです。これは sound または music チャンネルです。大抵これはチャンネル 7 で、デフォルトの music チャンネルです。

renpy.music.set_pause(value, channel='music') link

channel のポーズフラグを value に設定します。 True なら、チャンネルはポーズし、そうでなければ通常どおり再生します。

renpy.music.set_queue_empty_callback(callback, channel='music') link

これはキューが空になったときに呼び出されるコールバックを設定します。このコールバックはキューが最初に空になったときとキューが空になっている間のインタラクション毎に少なくとも 1 回呼び出されます。

コールバックは引数なしで呼び出されます。これは適切な引数で renpy.music.queue() を呼び出して曲をエンキュー出来ます。コールバックはキューが空である限り曲が再生されている間も呼び出されることに注意してください。

renpy.music.set_volume(volume, delay=0, channel='music') link

このチャンネルの音量を、チャンネルを制御するミキサーの音量の割合で設定します。

volume

これは 0.0 と 1.0 の間の数字で、そのチャンネルのミキサーボリュームの割合として解釈されます。

delay

以前の値から新しい値に音量を変更するのに delay 秒掛かります。この値はセーブに保存され、ロールバックにも参加します。

channel

設定されるチャンネルです。

renpy.music.stop(channel='music', fadeout=None) link

これは現在再生中の曲を停止して、エンキューされた全ての曲をデキューします。 fadeout が None なら曲は config.fade_music で指定された時間でフェードアウトします。そうでなければ fadeout 秒でフェードアウトします。

これは最後にキューされたファイルを None に設定します。

channel

再生を停止するチャンネル

fadeout

None を指定するか、フェードアウトにかかる秒数を指定します。そうでなければフェードアウトの時間は config.fade_music から取られます。

サウンドの関数 link

ほとんどの renpy.music 関数は renpy.sound にエイリアスを持ちます。これらの関数はデフォルトで music チャンネルではなく sound チャンネルに設定されており、ループしないことを除いて同じです。